convert/convert.ha


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

use fmt;

use mbr;
use gpt;
use sector;

use os;
use io;
use fs;
use strings;
use errors;
use rt;

use volume;

export fn convert(vol: str, args: []str) void = {
	if (len(args) < 2) {
		fmt::fatalf("convert: needs disk");
	};

	let source = os::open(args[1], fs::flags::RDONLY)!;
	defer io::close(source)!;

	const source = mbr::from(source)!;

	const vol = volume::openvol(vol);
	let vol = gpt::from(vol)!;
	defer {
		gpt::chksums(vol);
		gpt::commit(vol)!;
		gpt::finish(vol);
	};

	rt::memcpy(vol.mbr, source.bootsector, size(mbr::bootsector));	
	for (let i = 0z; i < 4; i += 1) {
		const entry = &source.bootsector.entries[i];
		if (entry.lba_begin == 0 && entry.length == 0)
			continue;

		const reader = mbr::partstream_reader(source, entry)!;
		const partlength = entry.length;

		const part = gpt::allocate(vol, partlength) as *gpt::entry;

		const writer = gpt::partstream_writer(vol, part)!;

		io::copy(&writer, &reader)!;

		vol.mbr.entries[i].lba_begin = part.lba_begin: u32;
		vol.mbr.entries[i].length = (part.lba_end - part.lba_begin + 1): u32;
	};

	vol.mbr.entries[3] = mbr::entry {
		part_type = 0xEE,
		lba_begin = 0,
		length = -1: u32,
		...
	};
};